[#Part: CMP TallyShopFeatures Left]
	Add : Line  : 	 Enable_AutoAdjustBills

[Line :  Enable_AutoAdjustBills]
    Field : medium prompt ,Enable_AutoAdjustBills
    Local : field : medium prompt : set as : "Auto Adjust Pending Bills against on FIFO Method ?"
    Local : Field : Medium Prompt : width : 40
	
    space top : 0.2 cm

[Field :  Enable_AutoAdjustBills]
   Use 		: Logical field
   Storage 	: Enable_AutoAdjustBills
     
[System: udf]
	Enable_AutoAdjustBills 	: Logical	: 191

[System: formula]
	Enable_AutoAdjustBills 	: $Enable_AutoAdjustBills:company:##svcurrentcompany
	
[#Report	: VCHBillAllocation]
	Variable	: AutoBill	: String

[#Form : VCHBillAllocation]
	Add	: Switch	: AutoBill	: TWS_AutoBillAdjust	: @@Enable_AutoAdjustBills and $$inCreateMode and (@@isReceipt OR @@isPayment)

[!Form : TWS_AutoBillAdjust]
	Add		: Set		: AutoBill	: $$TWS_AutoBillSet
	
[Function: TWS_AutoBillSet]
	10  : If : Yes
	
	;20	: 	QUERY BOX 	: "Developed By : Talllywebsolutions \n\n\n Do you want to Auto Adjust Pending Bills \n\n against on FIFo Method ? \n\n\n Process ?"
	20	: 	QUERY BOX 	: "Do you want to Auto Adjust Pending Bills \n\n against on FIFo Method ? \n\n\n Process ?"
 	30	: 	IF	: $$LastResult
 	31 	: 	Call	: TWS_AutoBillSet2
	
	45	: 	ELSE : 
	50	: 	Break	
	55  :	Endif
	
	60	: 	Break	
	65  :	Endif


[Function	: TWS_AutoBillSet2]
	Variable	: Counter		: Number
	Variable	: Temp			: Amount
	Variable	: CurrentAmt	: Amount
	
	02		: Set		: CurrentAmt	: 0
	03		: Set		: Temp		: 0
	04		: Set		: Counter		: 1
	
	05		: While					: ##Counter <= $$NumItems:TWS_AutoSetBills_Coll AND ##Temp < $Amount
`	06		: Set Object Values		: BillAllocations[##Counter].BillType	: "Agst Ref"
	07		: Set Object Values		: BillAllocations[##Counter].Name		: $$CollectionField:$Name:##Counter:TWS_AutoSetBills_Coll
	
	08		: Set		: CurrentAmt: $$CollectionField:$FinalBalance:##Counter:TWS_AutoSetBills_Coll
	09		: Set		: Temp		: $$NettAmount:##Temp:##CurrentAmt
	11		: Set		: Counter	: ##Counter + 1
	
	15		: End While
	
	16		: if		: ##Temp < $Amount
	17		: Set Object Values	: BillAllocations[##Counter].BillType	: "New Ref"
	18		: End if
	19		: Return	

[Collection : TWS_AutoSetBills_Coll]
	Type	: Bill
	Childof	: $LedgerName
	Fetch	: Parent, Name, ClosingBalance, FinalBalance,BillDate

	Sort	: @@Default		: $BillDate
	;TableSort: $$Date:$BillDate
	
	Filter	: TWS_AutoDrBillsFilter

[System : Formula]
	TWS_AutoDrBillsFilter	: Not $$isEmpty:$FinalBalance
